W3cubDocs

core.memory

This module provides an interface to the garbage collector used by applications written in the D programming language. It allows the garbage collector in the runtime to be swapped without affecting binary compatibility of applications.

Using this module is not necessary in typical D code. It is mostly useful when doing low-level memory management.

Notes to users

The GC is a conservative mark-and-sweep collector. It only runs a collection cycle when an allocation is requested of it, never otherwise. Hence, if the program is not doing allocations, there will be no GC collection pauses. The pauses occur because all threads the GC knows about are halted so the threads' stacks and registers can be scanned for references to GC allocated data.
The GC does not know about threads that were created by directly calling the OS/C runtime thread creation APIs and D threads that were detached from the D runtime after creation. Such threads will not be paused for a GC collection, and the GC might not detect references to GC allocated data held by them. This can cause memory corruption. There are several ways to resolve this issue:
1. Do not hold references to GC allocated data in such threads.
2. Register/unregister such data with calls to addRoot/removeRoot and addRange/removeRange.
3. Maintain another reference to that same data in another thread that the GC does know about.
4. Disable GC collection cycles while that thread is active with disable/enable.
5. Register the thread with the GC using core.thread.thread_attachThis/core.thread.thread_detachThis.

Notes to implementors

On POSIX systems, the signals SIGUSR1 and SIGUSR2 are reserved by this module for use in the garbage collector implementation. Typically, they will be used to stop and resume other threads when performing a collection, but an implementation may choose not to use this mechanism (or not stop the world at all, in the case of concurrent garbage collectors).
Registers, the stack, and any other memory locations added through the GC.addRange function are always scanned conservatively. This means that even if a variable is e.g. of type float, it will still be scanned for possible GC pointers. And, if the word-interpreted representation of the variable matches a GC-managed memory block's address, that memory block is considered live.
Implementations are free to scan the non-root heap in a precise manner, so that fields of types like float will not be considered relevant when scanning the heap. Thus, casting a GC pointer to an integral type (e.g. size_t) and storing it in a field of that type inside the GC heap may mean that it will not be recognized if the memory block was allocated with precise type info or with the GC.BlkAttr.NO_SCAN attribute.
Destructors will always be executed while other threads are active; that is, an implementation that stops the world must not execute destructors until the world has been resumed.
A destructor of an object must not access object references within the object. This means that an implementation is free to optimize based on this rule.
An implementation is free to perform heap compaction and copying so long as no valid GC pointers are invalidated in the process. However, memory allocated with GC.BlkAttr.NO_MOVE must not be moved/copied.
Implementations must support interior pointers. That is, if the only reference to a GC-managed memory block points into the middle of the block rather than the beginning (for example), the GC must consider the memory block live. The exception to this rule is when a memory block is allocated with the GC.BlkAttr.NO_INTERIOR attribute; it is the user's responsibility to make sure such memory blocks have a proper pointer to them when they should be considered live.
It is acceptable for an implementation to store bit flags into pointer values and GC-managed memory blocks, so long as such a trick is not visible to the application. In practice, this means that only a stop-the-world collector can do this.
Implementations are free to assume that GC pointers are only stored on word boundaries. Unaligned pointers may be ignored entirely.
Implementations are free to run collections at any point. It is, however, recommendable to only do so when an allocation attempt happens and there is insufficient memory available.

License:: Boost License 1.0

Authors:: Sean Kelly, Alex Rønne Petersen

Source: core/memory.d

struct GC

This struct encapsulates all garbage collection functionality for the D programming language.

struct Stats

Aggregation of GC stats to be exposed via public API

size_t usedSize: number of used bytes on the GC heap (might only get updated after a collection)
size_t freeSize: number of free bytes on the GC heap (might only get updated after a collection)

static nothrow void enable()

Enables automatic garbage collection behavior if collections have previously been suspended by a call to disable. This function is reentrant, and must be called once for every call to disable before automatic collections are enabled.

static nothrow void disable()

Disables automatic garbage collections performed to minimize the process footprint. Collections may continue to occur in instances where the implementation deems necessary for correct program behavior, such as during an out of memory condition. This function is reentrant, but enable must be called once for each call to disable.

static nothrow void collect()

Begins a full collection. While the meaning of this may change based on the garbage collector implementation, typical behavior is to scan all stack segments for roots, mark accessible memory blocks as alive, and then to reclaim free space. This action may need to suspend all running threads for at least part of the collection process.

static nothrow void minimize()

Indicates that the managed memory space be minimized by returning free physical memory to the operating system. The amount of free memory returned depends on the allocator design and on program behavior.

enum BlkAttr: uint

Elements for a bit field representing memory block attributes. These are manipulated via the getAttr, setAttr, clrAttr functions.

NONE

No attributes set.

FINALIZE

Finalize the data in this block on collect.

NO_SCAN

Do not scan through this block on collect.

NO_MOVE

Do not move this memory block on collect.

APPENDABLE

This block contains the info to allow appending.

This can be used to manually allocate arrays. Initial slice size is 0.

Note: The slice's usable size will not match the block size. Use capacity to retrieve actual usable capacity.

Example

// Allocate the underlying array.
int*  pToArray = cast(int*)GC.malloc(10 * int.sizeof, GC.BlkAttr.NO_SCAN | GC.BlkAttr.APPENDABLE);
// Bind a slice. Check the slice has capacity information.
int[] slice = pToArray[0 .. 0];
assert(capacity(slice) > 0);
// Appending to the slice will not relocate it.
slice.length = 5;
slice ~= 1;
assert(slice.ptr == p);

NO_INTERIOR

This block is guaranteed to have a pointer to its base while it is alive. Interior pointers can be safely ignored. This attribute is useful for eliminating false pointers in very large data structures and is only implemented for data structures at least a page in size.

alias BlkInfo = .BlkInfo_

Contains aggregate information about a block of managed memory. The purpose of this struct is to support a more efficient query style in instances where detailed information is needed.

base = A pointer to the base of the block in question. size = The size of the block, calculated from base. attr = Attribute bits set on the memory block.

static nothrow uint getAttr(in void* p) static pure nothrow uint getAttr(void* p)

Returns a bit field representing all block attributes set for the memory referenced by p. If p references memory not originally allocated by this garbage collector, points to the interior of a memory block, or if p is null, zero will be returned.

Parameters:

void* p A pointer to the root of a valid memory block or to null.

Returns:: A bit field containing any bits set for the memory block referenced by p or zero on error.

static nothrow uint setAttr(in void* p, uint a) static pure nothrow uint setAttr(void* p, uint a)

Sets the specified bits for the memory references by p. If p references memory not originally allocated by this garbage collector, points to the interior of a memory block, or if p is null, no action will be performed.

Parameters:

void* `p`	A pointer to the root of `a` valid memory block or to `null`.
uint `a`	A bit field containing any bits to set for this memory block.

Returns:: The result of a call to getAttr after the specified bits have been set.

static nothrow uint clrAttr(in void* p, uint a) static pure nothrow uint clrAttr(void* p, uint a)

Clears the specified bits for the memory references by p. If p references memory not originally allocated by this garbage collector, points to the interior of a memory block, or if p is null, no action will be performed.

Parameters:

void* `p`	A pointer to the root of `a` valid memory block or to `null`.
uint `a`	A bit field containing any bits to clear for this memory block.

Returns:: The result of a call to getAttr after the specified bits have been cleared.

static pure nothrow void* malloc(size_t sz, uint ba = 0, const TypeInfo ti = null)

Requests an aligned block of managed memory from the garbage collector. This memory may be deleted at will with a call to free, or it may be discarded and cleaned up automatically during a collection run. If allocation fails, this function will call onOutOfMemory which is expected to throw an OutOfMemoryError.

Parameters:

size_t `sz`	The desired allocation size in bytes.
uint `ba`	A bitmask of the attributes to set on this block.
TypeInfo `ti`	TypeInfo to describe the memory. The GC might use this information to improve scanning for pointers or to call finalizers.

Returns:: A reference to the allocated memory or null if insufficient memory is available.

Throws:: OutOfMemoryError on allocation failure.

static pure nothrow BlkInfo qalloc(size_t sz, uint ba = 0, const TypeInfo ti = null)

Parameters:

size_t `sz`	The desired allocation size in bytes.
uint `ba`	A bitmask of the attributes to set on this block.
TypeInfo `ti`	TypeInfo to describe the memory. The GC might use this information to improve scanning for pointers or to call finalizers.

Returns:: Information regarding the allocated memory block or BlkInfo.init on error.

Throws:: OutOfMemoryError on allocation failure.

static pure nothrow void* calloc(size_t sz, uint ba = 0, const TypeInfo ti = null)

Requests an aligned block of managed memory from the garbage collector, which is initialized with all bits set to zero. This memory may be deleted at will with a call to free, or it may be discarded and cleaned up automatically during a collection run. If allocation fails, this function will call onOutOfMemory which is expected to throw an OutOfMemoryError.

Parameters:

size_t `sz`	The desired allocation size in bytes.
uint `ba`	A bitmask of the attributes to set on this block.
TypeInfo `ti`	TypeInfo to describe the memory. The GC might use this information to improve scanning for pointers or to call finalizers.

Returns:: A reference to the allocated memory or null if insufficient memory is available.

Throws:: OutOfMemoryError on allocation failure.

static pure nothrow void* realloc(void* p, size_t sz, uint ba = 0, const TypeInfo ti = null)

If sz is zero, the memory referenced by p will be deallocated as if by a call to free. A new memory block of size sz will then be allocated as if by a call to malloc, or the implementation may instead resize the memory block in place. The contents of the new memory block will be the same as the contents of the old memory block, up to the lesser of the new and old sizes. Note that existing memory will only be freed by realloc if sz is equal to zero. The garbage collector is otherwise expected to later reclaim the memory block if it is unused. If allocation fails, this function will call onOutOfMemory which is expected to throw an OutOfMemoryError. If p references memory not originally allocated by this garbage collector, or if it points to the interior of a memory block, no action will be taken. If ba is zero (the default) and p references the head of a valid, known memory block then any bits set on the current block will be set on the new block if a reallocation is required. If ba is not zero and p references the head of a valid, known memory block then the bits in ba will replace those on the current memory block and will also be set on the new block if a reallocation is required.

Parameters:

void* `p`	A pointer to the root of a valid memory block or to `null`.
size_t `sz`	The desired allocation size in bytes.
uint `ba`	A bitmask of the attributes to set on this block.
TypeInfo `ti`	TypeInfo to describe the memory. The GC might use this information to improve scanning for pointers or to call finalizers.

Returns:: A reference to the allocated memory on success or null if sz is zero. On failure, the original value of p is returned.

Throws:: OutOfMemoryError on allocation failure.

Examples:

Issue 13111

enum size1 = 1 << 11 + 1; // page in large object pool
enum size2 = 1 << 22 + 1; // larger than large object pool size

auto data1 = cast(ubyte*)GC.calloc(size1);
auto data2 = cast(ubyte*)GC.realloc(data1, size2);

BlkInfo info = query(data2);
assert(info.size >= size2);

static pure nothrow size_t extend(void* p, size_t mx, size_t sz, const TypeInfo ti = null)

Requests that the managed memory block referenced by p be extended in place by at least mx bytes, with a desired extension of sz bytes. If an extension of the required size is not possible or if p references memory not originally allocated by this garbage collector, no action will be taken.

Parameters:

void* `p`	A pointer to the root of a valid memory block or to `null`.
size_t `mx`	The minimum extension size in bytes.
size_t `sz`	The desired extension size in bytes.
TypeInfo `ti`	TypeInfo to describe the full memory block. The GC might use this information to improve scanning for pointers or to call finalizers.

Returns:: The size in bytes of the extended memory block referenced by p or zero if no extension occurred.

Note: Extend may also be used to extend slices (or memory blocks with APPENDABLE info). However, use the return value only as an indicator of success. capacity should be used to retrieve actual usable slice capacity.

Examples:

Standard extending

size_t size = 1000;
int* p = cast(int*)GC.malloc(size * int.sizeof, GC.BlkAttr.NO_SCAN);

//Try to extend the allocated data by 1000 elements, preferred 2000.
size_t u = GC.extend(p, 1000 * int.sizeof, 2000 * int.sizeof);
if (u != 0)
    size = u / int.sizeof;

Examples:

slice extending

int[] slice = new int[](1000);
int*  p     = slice.ptr;

//Check we have access to capacity before attempting the extend
if (slice.capacity)
{
    //Try to extend slice by 1000 elements, preferred 2000.
    size_t u = GC.extend(p, 1000 * int.sizeof, 2000 * int.sizeof);
    if (u != 0)
    {
        slice.length = slice.capacity;
        assert(slice.length >= 2000);
    }
}

static nothrow size_t reserve(size_t sz)

Requests that at least sz bytes of memory be obtained from the operating system and marked as free.

Parameters:

size_t sz The desired size in bytes.

Returns:: The actual number of bytes reserved or zero on error.

static pure nothrow void free(void* p)

Deallocates the memory referenced by p. If p is null, no action occurs. If p references memory not originally allocated by this garbage collector, if p points to the interior of a memory block, or if this method is called from a finalizer, no action will be taken. The block will not be finalized regardless of whether the FINALIZE attribute is set. If finalization is desired, use delete instead.

Parameters:

void* p A pointer to the root of a valid memory block or to null.

static nothrow inout(void)* addrOf(inout(void)* p) static pure nothrow void* addrOf(void* p)

Returns the base address of the memory block containing p. This value is useful to determine whether p is an interior pointer, and the result may be passed to routines such as sizeOf which may otherwise fail. If p references memory not originally allocated by this garbage collector, if p is null, or if the garbage collector does not support this operation, null will be returned.

Parameters:

inout(void)* p A pointer to the root or the interior of a valid memory block or to null.

Returns:: The base address of the memory block referenced by p or null on error.

static nothrow size_t sizeOf(in void* p) static pure nothrow size_t sizeOf(void* p)

Returns the true size of the memory block referenced by p. This value represents the maximum number of bytes for which a call to realloc may resize the existing block in place. If p references memory not originally allocated by this garbage collector, points to the interior of a memory block, or if p is null, zero will be returned.

Parameters:

void* p A pointer to the root of a valid memory block or to null.

Returns:: The size in bytes of the memory block referenced by p or zero on error.

static nothrow BlkInfo query(in void* p) static pure nothrow BlkInfo query(void* p)

Returns aggregate information about the memory block containing p. If p references memory not originally allocated by this garbage collector, if p is null, or if the garbage collector does not support this operation, BlkInfo.init will be returned. Typically, support for this operation is dependent on support for addrOf.

Parameters:

void* p A pointer to the root or the interior of a valid memory block or to null.

Returns:: Information regarding the memory block referenced by p or BlkInfo.init on error.

static nothrow Stats stats()

Returns runtime stats for currently active GC implementation See core.memory.GC.Stats for list of available metrics.

static nothrow @nogc void addRoot(in void* p)

Adds an internal root pointing to the GC memory block referenced by p. As a result, the block referenced by p itself and any blocks accessible via it will be considered live until the root is removed again.

If p is null, no operation is performed.

Parameters:

void* p A pointer into a GC-managed memory block or null.

Example

// Typical C-style callback mechanism; the passed function
// is invoked with the user-supplied context pointer at a
// later point.
extern(C) void addCallback(void function(void*), void*);

// Allocate an object on the GC heap (this would usually be
// some application-specific context data).
auto context = new Object;

// Make sure that it is not collected even if it is no
// longer referenced from D code (stack, GC heap, …).
GC.addRoot(cast(void*)context);

// Also ensure that a moving collector does not relocate
// the object.
GC.setAttr(cast(void*)context, GC.BlkAttr.NO_MOVE);

// Now context can be safely passed to the C library.
addCallback(&myHandler, cast(void*)context);

extern(C) void myHandler(void* ctx)
{
    // Assuming that the callback is invoked only once, the
    // added root can be removed again now to allow the GC
    // to collect it later.
    GC.removeRoot(ctx);
    GC.clrAttr(ctx, GC.BlkAttr.NO_MOVE);

    auto context = cast(Object)ctx;
    // Use context here…
}

static nothrow @nogc void removeRoot(in void* p)

Removes the memory block referenced by p from an internal list of roots to be scanned during a collection. If p is null or is not a value previously passed to addRoot() then no operation is performed.

Parameters:

void* p A pointer into a GC-managed memory block or null.

static nothrow @nogc void addRange(in void* p, size_t sz, const TypeInfo ti = null)

Adds p[0 .. sz] to the list of memory ranges to be scanned for pointers during a collection. If p is null, no operation is performed.

Note that p[0 .. sz] is treated as an opaque range of memory assumed to be suitably managed by the caller. In particular, if p points into a GC-managed memory block, addRange does not mark this block as live.

Parameters:

void* `p`	A pointer to a valid memory address or to `null`.
size_t `sz`	The size in bytes of the block to add. If `sz` is zero then the no operation will occur. If `p` is `null` then `sz` must be zero.
TypeInfo `ti`	TypeInfo to describe the memory. The GC might use this information to improve scanning for pointers or to call finalizers

Example

// Allocate a piece of memory on the C heap.
enum size = 1_000;
auto rawMemory = core.stdc.stdlib.malloc(size);

// Add it as a GC range.
GC.addRange(rawMemory, size);

// Now, pointers to GC-managed memory stored in
// rawMemory will be recognized on collection.

static nothrow @nogc void removeRange(in void* p)

Removes the memory range starting at p from an internal list of ranges to be scanned during a collection. If p is null or does not represent a value previously passed to addRange() then no operation is performed.

Parameters:

void* p A pointer to a valid memory address or to null.

static void runFinalizers(in void[] segment)

Runs any finalizer that is located in address range of the given code segment. This is used before unloading shared libraries. All matching objects which have a finalizer in this code segment are assumed to be dead, using them while or after calling this method has undefined behavior.

Parameters:

void[] segment address range of a code segment.

pure nothrow @nogc @trusted void* pureMalloc(size_t size) pure nothrow @nogc @trusted void* pureCalloc(size_t nmemb, size_t size) pure nothrow @nogc @system void* pureRealloc(void* ptr, size_t size) pure nothrow @nogc @system void pureFree(void* ptr)

Pure variants of C's memory allocation functions malloc, calloc, and realloc and deallocation function free.

Purity is achieved by saving and restoring the value of errno, thus behaving as if it were never changed.

See Also:: D's rules for purity, which allow for memory allocation under specific circumstances.

Examples:

ubyte[] fun(size_t n) pure
{
    void* p = pureMalloc(n);
    p !is null || n == 0 || assert(0);
    scope(failure) p = pureRealloc(p, 0);
    p = pureRealloc(p, n *= 2);
    p !is null || n == 0 || assert(0);
    return cast(ubyte[]) p[0 .. n];
}

auto buf = fun(100);
assert(buf.length == 200);
pureFree(buf.ptr);