| Copyright | (c) Universiteit Utrecht 2010-2011 University of Oxford 2012-2014 |
|---|---|
| License | see libraries/base/LICENSE |
| Maintainer | [email protected] |
| Stability | internal |
| Portability | non-portable |
| Safe Haskell | Trustworthy |
| Language | Haskell2010 |
If you're using GHC.Generics, you should consider using the http://hackage.haskell.org/package/generic-deriving package, which contains many useful generic functions.
Since: 4.6.0.0
Datatype-generic functions are based on the idea of converting values of a datatype T into corresponding values of a (nearly) isomorphic type Rep T. The type Rep T is built from a limited set of type constructors, all provided by this module. A datatype-generic function is then an overloaded function with instances for most of these type constructors, together with a wrapper that performs the mapping between T and Rep T. By using this technique, we merely need a few generic instances in order to implement functionality that works for any representable type.
Representable types are collected in the Generic class, which defines the associated type Rep as well as conversion functions from and to. Typically, you will not define Generic instances by hand, but have the compiler derive them for you.
The key to defining your own datatype-generic functions is to understand how to represent datatypes using the given set of type constructors.
Let us look at an example first:
data Tree a = Leaf a | Node (Tree a) (Tree a)
deriving Generic
The above declaration (which requires the language pragma DeriveGeneric) causes the following representation to be generated:
instanceGeneric(Tree a) where typeRep(Tree a) =D1('MetaData "Tree" "Main" "package-name" 'False) (C1('MetaCons "Leaf" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec0a)):+:C1('MetaCons "Node" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec0(Tree a)):*:S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec0(Tree a)))) ...
Hint: You can obtain information about the code being generated from GHC by passing the -ddump-deriv flag. In GHCi, you can expand a type family such as Rep using the :kind! command.
This is a lot of information! However, most of it is actually merely meta-information that makes names of datatypes and constructors and more available on the type level.
Here is a reduced representation for Tree with nearly all meta-information removed, for now keeping only the most essential aspects:
instanceGeneric(Tree a) where typeRep(Tree a) =Rec0a:+:(Rec0(Tree a):*:Rec0(Tree a))
The Tree datatype has two constructors. The representation of individual constructors is combined using the binary type constructor :+:.
The first constructor consists of a single field, which is the parameter a. This is represented as Rec0 a.
The second constructor consists of two fields. Each is a recursive field of type Tree a, represented as Rec0 (Tree a). Representations of individual fields are combined using the binary type constructor :*:.
Now let us explain the additional tags being used in the complete representation:
S1 ('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness
'DecidedLazy) tag indicates several things. The 'Nothing indicates that there is no record field selector associated with this field of the constructor (if there were, it would have been marked 'Just
"recordName" instead). The other types contain meta-information on the field's strictness:{-# UNPACK #-} or {-# NOUNPACK #-} annotation in the source, so it is tagged with 'NoSourceUnpackedness.!) or laziness (~) annotation in the source, so it is tagged with 'NoSourceStrictness.'DecidedLazy. Bear in mind that what the compiler decides may be quite different from what is written in the source. See DecidedStrictness for a more detailed explanation.The 'MetaSel type is also an instance of the type class Selector, which can be used to obtain information about the field at the value level.
C1 ('MetaCons "Leaf" 'PrefixI 'False) and C1 ('MetaCons "Node" 'PrefixI 'False) invocations indicate that the enclosed part is the representation of the first and second constructor of datatype Tree, respectively. Here, the meta-information regarding constructor names, fixity and whether it has named fields or not is encoded at the type level. The 'MetaCons type is also an instance of the type class Constructor. This type class can be used to obtain information about the constructor at the value level.D1 ('MetaData "Tree" "Main" "package-name" 'False) tag indicates that the enclosed part is the representation of the datatype Tree. Again, the meta-information is encoded at the type level. The 'MetaData type is an instance of class Datatype, which can be used to obtain the name of a datatype, the module it has been defined in, the package it is located under, and whether it has been defined using data or newtype at the value level.There are many datatype-generic functions that do not distinguish between positions that are parameters or positions that are recursive calls. There are also many datatype-generic functions that do not care about the names of datatypes and constructors at all. To keep the number of cases to consider in generic functions in such a situation to a minimum, it turns out that many of the type constructors introduced above are actually synonyms, defining them to be variants of a smaller set of constructors.
K1
The type constructor Rec0 is a variant of K1:
typeRec0=K1R
Here, R is a type-level proxy that does not have any associated values.
There used to be another variant of K1 (namely Par0), but it has since been deprecated.
M1
The type constructors S1, C1 and D1 are all variants of M1:
typeS1=M1StypeC1=M1CtypeD1=M1D
The types S, C and D are once again type-level proxies, just used to create several variants of M1.
Next to K1, M1, :+: and :*: there are a few more type constructors that occur in the representations of other datatypes.
V1
For empty datatypes, V1 is used as a representation. For example,
data Empty deriving Generic
yields
instanceGenericEmpty where typeRepEmpty =D1('MetaData "Empty" "Main" "package-name" 'False)V1
U1
If a constructor has no arguments, then U1 is used as its representation. For example the representation of Bool is
instanceGenericBool where typeRepBool =D1('MetaData "Bool" "Data.Bool" "package-name" 'False) (C1('MetaCons "False" 'PrefixI 'False)U1:+:C1('MetaCons "True" 'PrefixI 'False)U1)
As :+: and :*: are just binary operators, one might ask what happens if the datatype has more than two constructors, or a constructor with more than two fields. The answer is simple: the operators are used several times, to combine all the constructors and fields as needed. However, users /should not rely on a specific nesting strategy/ for :+: and :*: being used. The compiler is free to choose any nesting it prefers. (In practice, the current implementation tries to produce a more or less balanced nesting, so that the traversal of the structure of the datatype from the root to a particular component can be performed in logarithmic rather than linear time.)
A datatype-generic function comprises two parts:
Generic, performs the conversion between the original value and its Rep-based representation and then invokes the generic instances.As an example, let us look at a function encode that produces a naive, but lossless bit encoding of values of various datatypes. So we are aiming to define a function
encode :: Generic a => a -> [Bool]
where we use Bool as our datatype for bits.
For part 1, we define a class Encode'. Perhaps surprisingly, this class is parameterized over a type constructor f of kind * -> *. This is a technicality: all the representation type constructors operate with kind * -> * as base kind. But the type argument is never being used. This may be changed at some point in the future. The class has a single method, and we use the type we want our final function to have, but we replace the occurrences of the generic type argument a with f p (where the p is any argument; it will not be used).
class Encode' f where encode' :: f p -> [Bool]
With the goal in mind to make encode work on Tree and other datatypes, we now define instances for the representation type constructors V1, U1, :+:, :*:, K1, and M1.
In order to be able to do this, we need to know the actual definitions of these types:
dataV1p -- lifted version of Empty dataU1p =U1-- lifted version of () data (:+:) f g p =L1(f p) |R1(g p) -- lifted version ofEitherdata (:*:) f g p = (f p):*:(g p) -- lifted version of (,) newtypeK1i c p =K1{unK1:: c } -- a container for a c newtypeM1i t f p =M1{unM1:: f p } -- a wrapper
So, U1 is just the unit type, :+: is just a binary choice like Either, :*: is a binary pair like the pair constructor (,), and K1 is a value of a specific type c, and M1 wraps a value of the generic type argument, which in the lifted world is an f p (where we do not care about p).
The instance for V1 is slightly awkward (but also rarely used):
instance Encode' V1 where
encode' x = undefined
There are no values of type V1 p to pass (except undefined), so this is actually impossible. One can ask why it is useful to define an instance for V1 at all in this case? Well, an empty type can be used as an argument to a non-empty type, and you might still want to encode the resulting type. As a somewhat contrived example, consider [Empty], which is not an empty type, but contains just the empty list. The V1 instance ensures that we can call the generic function on such types.
There is exactly one value of type U1, so encoding it requires no knowledge, and we can use zero bits:
instance Encode'U1where encode'U1= []
In the case for :+:, we produce False or True depending on whether the constructor of the value provided is located on the left or on the right:
instance (Encode' f, Encode' g) => Encode' (f:+:g) where encode' (L1x) = False : encode' x encode' (R1x) = True : encode' x
In the case for :*:, we append the encodings of the two subcomponents:
instance (Encode' f, Encode' g) => Encode' (f:*:g) where encode' (x:*:y) = encode' x ++ encode' y
The case for K1 is rather interesting. Here, we call the final function encode that we yet have to define, recursively. We will use another type class Encode for that function:
instance (Encode c) => Encode' (K1i c) where encode' (K1x) = encode x
Note how Par0 and Rec0 both being mapped to K1 allows us to define a uniform instance here.
Similarly, we can define a uniform instance for M1, because we completely disregard all meta-information:
instance (Encode' f) => Encode' (M1i t f) where encode' (M1x) = encode' x
Unlike in K1, the instance for M1 refers to encode', not encode.
We now define class Encode for the actual encode function:
class Encode a where
encode :: a -> [Bool]
default encode :: (Generic a, Encode' (Rep a)) => a -> [Bool]
encode x = encode' (from x)
The incoming x is converted using from, then we dispatch to the generic instances using encode'. We use this as a default definition for encode. We need the 'default encode' signature because ordinary Haskell default methods must not introduce additional class constraints, but our generic default does.
Defining a particular instance is now as simple as saying
instance (Encode a) => Encode (Tree a)
It is not always required to provide instances for all the generic representation types, but omitting instances restricts the set of datatypes the functions will work for:
:+: instance is given, the function may still work for empty datatypes or datatypes that have a single constructor, but will fail on datatypes with more than one constructor.:*: instance is given, the function may still work for datatypes where each constructor has just zero or one field, in particular for enumeration types.K1 instance is given, the function may still work for enumeration types, where no constructor has any fields.V1 instance is given, the function may still work for any datatype that is not empty.U1 instance is given, the function may still work for any datatype where each constructor has at least one field.An M1 instance is always required (but it can just ignore the meta-information, as is the case for encode above).
Datatype-generic functions as defined above work for a large class of datatypes, including parameterized datatypes. (We have used Tree as our example above, which is of kind * -> *.) However, the Generic class ranges over types of kind *, and therefore, the resulting generic functions (such as encode) must be parameterized by a generic type argument of kind *.
What if we want to define generic classes that range over type constructors (such as Functor, Traversable, or Foldable)?
Generic1 classLike Generic, there is a class Generic1 that defines a representation Rep1 and conversion functions from1 and to1, only that Generic1 ranges over types of kind * -> *. (More generally, it can range over types of kind k -> *, for any kind k, if the PolyKinds extension is enabled. More on this later.) The Generic1 class is also derivable.
The representation Rep1 is ever so slightly different from Rep. Let us look at Tree as an example again:
data Tree a = Leaf a | Node (Tree a) (Tree a)
deriving Generic1
The above declaration causes the following representation to be generated:
instanceGeneric1Tree where typeRep1Tree =D1('MetaData "Tree" "Main" "package-name" 'False) (C1('MetaCons "Leaf" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy)Par1):+:C1('MetaCons "Node" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec1Tree):*:S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec1Tree))) ...
The representation reuses D1, C1, S1 (and thereby M1) as well as :+: and :*: from Rep. (This reusability is the reason that we carry around the dummy type argument for kind-*-types, but there are already enough different names involved without duplicating each of these.)
What's different is that we now use Par1 to refer to the parameter (and that parameter, which used to be a), is not mentioned explicitly by name anywhere; and we use Rec1 to refer to a recursive use of Tree a.
* -> * typesUnlike Rec0, the Par1 and Rec1 type constructors do not map to K1. They are defined directly, as follows:
newtypePar1p =Par1{unPar1:: p } -- gives access to parameter p newtypeRec1f p =Rec1{unRec1:: f p } -- a wrapper
In Par1, the parameter p is used for the first time, whereas Rec1 simply wraps an application of f to p.
Note that K1 (in the guise of Rec0) can still occur in a Rep1 representation, namely when the datatype has a field that does not mention the parameter.
The declaration
data WithInt a = WithInt Int a
deriving Generic1
yields
instanceGeneric1WithInt where typeRep1WithInt =D1('MetaData "WithInt" "Main" "package-name" 'False) (C1('MetaCons "WithInt" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) (Rec0Int):*:S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy)Par1))
If the parameter a appears underneath a composition of other type constructors, then the representation involves composition, too:
data Rose a = Fork a [Rose a]
yields
instanceGeneric1Rose where typeRep1Rose =D1('MetaData "Rose" "Main" "package-name" 'False) (C1('MetaCons "Fork" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy)Par1:*:S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy) ([]:.:Rec1Rose)))
where
newtype (:.:) f g p =Comp1{unComp1:: f (g p) }
k -> * typesThe Generic1 class can be generalized to range over types of kind k -> *, for any kind k. To do so, derive a Generic1 instance with the PolyKinds extension enabled. For example, the declaration
data Proxy (a :: k) = Proxy deriving Generic1
yields a slightly different instance depending on whether PolyKinds is enabled. If compiled without PolyKinds, then Rep1 Proxy :: * -> *, but if compiled with PolyKinds, then Rep1 Proxy :: k -> *.
If one were to attempt to derive a Generic instance for a datatype with an unlifted argument (for example, Int#), one might expect the occurrence of the Int# argument to be marked with Rec0 Int#. This won't work, though, since Int# is of an unlifted kind, and Rec0 expects a type of kind *.
One solution would be to represent an occurrence of Int# with 'Rec0 Int' instead. With this approach, however, the programmer has no way of knowing whether the Int is actually an Int# in disguise.
Instead of reusing Rec0, a separate data family URec is used to mark occurrences of common unlifted types:
data family URec a p data instanceURec(Ptr()) p =UAddr{uAddr#::Addr#} data instanceURecCharp =UChar{uChar#::Char#} data instanceURecDoublep =UDouble{uDouble#::Double#} data instanceURecIntp =UFloat{uFloat#::Float#} data instanceURecFloatp =UInt{uInt#::Int#} data instanceURecWordp =UWord{uWord#::Word#}
Several type synonyms are provided for convenience:
typeUAddr=URec(Ptr()) typeUChar=URecChartypeUDouble=URecDoubletypeUFloat=URecFloattypeUInt=URecInttypeUWord=URecWord
The declaration
data IntHash = IntHash Int#
deriving Generic
yields
instanceGenericIntHash where typeRepIntHash =D1('MetaData "IntHash" "Main" "package-name" 'False) (C1('MetaCons "IntHash" 'PrefixI 'False) (S1('MetaSel 'Nothing 'NoSourceUnpackedness 'NoSourceStrictness 'DecidedLazy)UInt))
Currently, only the six unlifted types listed above are generated, but this may be extended to encompass more unlifted types in the future.
Void: used for datatypes without constructors
Unit: used for constructors without arguments
| U1 |
| Generic1 k (U1 k) | |
| Monad (U1 *) | Since: 4.9.0.0 |
| Functor (U1 *) | Since: 4.9.0.0 |
| Applicative (U1 *) | Since: 4.9.0.0 |
| Foldable (U1 *) | Since: 4.9.0.0 |
| Traversable (U1 *) | Since: 4.9.0.0 |
| MonadPlus (U1 *) | Since: 4.9.0.0 |
| Alternative (U1 *) | Since: 4.9.0.0 |
| MonadZip (U1 *) | Since: 4.9.0.0 |
| Eq (U1 k p) | Since: 4.9.0.0 |
| Data p => Data (U1 * p) | Since: 4.9.0.0 |
| Ord (U1 k p) | Since: 4.9.0.0 |
| Read (U1 k p) | Since: 4.9.0.0 |
| Show (U1 k p) | Since: 4.9.0.0 |
| Generic (U1 k p) | |
| type Rep1 k (U1 k) | |
| type Rep (U1 k p) | |
Used for marking occurrences of the parameter
| Monad Par1 | Since: 4.9.0.0 |
| Functor Par1 | |
| MonadFix Par1 | Since: 4.9.0.0 |
| Applicative Par1 | Since: 4.9.0.0 |
| Foldable Par1 | |
| Traversable Par1 | |
| MonadZip Par1 | Since: 4.9.0.0 |
| Eq p => Eq (Par1 p) | |
| Data p => Data (Par1 p) | Since: 4.9.0.0 |
| Ord p => Ord (Par1 p) | |
| Read p => Read (Par1 p) | |
| Show p => Show (Par1 p) | |
| Generic (Par1 p) | |
| Generic1 * Par1 | |
| type Rep (Par1 p) | |
| type Rep1 * Par1 | |
newtype Rec1 (f :: k -> *) (p :: k) Source
Recursive calls of kind * -> * (or kind k -> *, when PolyKinds is enabled)
| Generic1 k (Rec1 k f) | |
| Monad f => Monad (Rec1 * f) | Since: 4.9.0.0 |
| Functor f => Functor (Rec1 * f) | |
| MonadFix f => MonadFix (Rec1 * f) | Since: 4.9.0.0 |
| Applicative f => Applicative (Rec1 * f) | Since: 4.9.0.0 |
| Foldable f => Foldable (Rec1 * f) | |
| Traversable f => Traversable (Rec1 * f) | |
| MonadPlus f => MonadPlus (Rec1 * f) | Since: 4.9.0.0 |
| Alternative f => Alternative (Rec1 * f) | Since: 4.9.0.0 |
| MonadZip f => MonadZip (Rec1 * f) | Since: 4.9.0.0 |
| Eq (f p) => Eq (Rec1 k f p) | |
| (Data (f p), Typeable (* -> *) f, Data p) => Data (Rec1 * f p) | Since: 4.9.0.0 |
| Ord (f p) => Ord (Rec1 k f p) | |
| Read (f p) => Read (Rec1 k f p) | |
| Show (f p) => Show (Rec1 k f p) | |
| Generic (Rec1 k f p) | |
| type Rep1 k (Rec1 k f) | |
| type Rep (Rec1 k f p) | |
newtype K1 (i :: *) c (p :: k) Source
Constants, additional parameters and recursion of kind *
| Generic1 k (K1 k i c) | |
| Bifunctor (K1 * i) | Since: 4.9.0.0 |
| Bifoldable (K1 * i) | Since: 4.10.0.0 |
| Bitraversable (K1 * i) | Since: 4.10.0.0 |
| Functor (K1 * i c) | |
| Foldable (K1 * i c) | |
| Traversable (K1 * i c) | |
| Eq c => Eq (K1 k i c p) | |
| (Typeable * i, Data p, Data c) => Data (K1 * i c p) | Since: 4.9.0.0 |
| Ord c => Ord (K1 k i c p) | |
| Read c => Read (K1 k i c p) | |
| Show c => Show (K1 k i c p) | |
| Generic (K1 k i c p) | |
| type Rep1 k (K1 k i c) | |
| type Rep (K1 k i c p) | |
newtype M1 (i :: *) (c :: Meta) (f :: k -> *) (p :: k) Source
Meta-information (constructor names, etc.)
| Generic1 k (M1 k i c f) | |
| Monad f => Monad (M1 * i c f) | Since: 4.9.0.0 |
| Functor f => Functor (M1 * i c f) | |
| MonadFix f => MonadFix (M1 * i c f) | Since: 4.9.0.0 |
| Applicative f => Applicative (M1 * i c f) | Since: 4.9.0.0 |
| Foldable f => Foldable (M1 * i c f) | |
| Traversable f => Traversable (M1 * i c f) | |
| MonadPlus f => MonadPlus (M1 * i c f) | Since: 4.9.0.0 |
| Alternative f => Alternative (M1 * i c f) | Since: 4.9.0.0 |
| MonadZip f => MonadZip (M1 * i c f) | Since: 4.9.0.0 |
| Eq (f p) => Eq (M1 k i c f p) | |
| (Data p, Data (f p), Typeable Meta c, Typeable * i, Typeable (* -> *) f) => Data (M1 * i c f p) | Since: 4.9.0.0 |
| Ord (f p) => Ord (M1 k i c f p) | |
| Read (f p) => Read (M1 k i c f p) | |
| Show (f p) => Show (M1 k i c f p) | |
| Generic (M1 k i c f p) | |
| type Rep1 k (M1 k i c f) | |
| type Rep (M1 k i c f p) | |
data ((f :: k -> *) :+: (g :: k -> *)) (p :: k) infixr 5 Source
Sums: encode choice between constructors
| Generic1 k ((:+:) k f g) | |
| (Functor g, Functor f) => Functor ((:+:) * f g) | |
| (Foldable f, Foldable g) => Foldable ((:+:) * f g) | |
| (Traversable f, Traversable g) => Traversable ((:+:) * f g) | |
| (Eq (g p), Eq (f p)) => Eq ((:+:) k f g p) | |
| (Typeable (* -> *) f, Typeable (* -> *) g, Data p, Data (f p), Data (g p)) => Data ((:+:) * f g p) | Since: 4.9.0.0 |
| (Ord (g p), Ord (f p)) => Ord ((:+:) k f g p) | |
| (Read (g p), Read (f p)) => Read ((:+:) k f g p) | |
| (Show (g p), Show (f p)) => Show ((:+:) k f g p) | |
| Generic ((:+:) k f g p) | |
| type Rep1 k ((:+:) k f g) | |
| type Rep ((:+:) k f g p) | |
data ((f :: k -> *) :*: (g :: k -> *)) (p :: k) infixr 6 Source
Products: encode multiple arguments to constructors
| (f p) :*: (g p) infixr 6 |
| Generic1 k ((:*:) k f g) | |
| (Monad f, Monad g) => Monad ((:*:) * f g) | Since: 4.9.0.0 |
| (Functor g, Functor f) => Functor ((:*:) * f g) | |
| (MonadFix f, MonadFix g) => MonadFix ((:*:) * f g) | Since: 4.9.0.0 |
| (Applicative f, Applicative g) => Applicative ((:*:) * f g) | Since: 4.9.0.0 |
| (Foldable f, Foldable g) => Foldable ((:*:) * f g) | |
| (Traversable f, Traversable g) => Traversable ((:*:) * f g) | |
| (MonadPlus f, MonadPlus g) => MonadPlus ((:*:) * f g) | Since: 4.9.0.0 |
| (Alternative f, Alternative g) => Alternative ((:*:) * f g) | Since: 4.9.0.0 |
| (MonadZip f, MonadZip g) => MonadZip ((:*:) * f g) | Since: 4.9.0.0 |
| (Eq (g p), Eq (f p)) => Eq ((:*:) k f g p) | |
| (Typeable (* -> *) f, Typeable (* -> *) g, Data p, Data (f p), Data (g p)) => Data ((:*:) * f g p) | Since: 4.9.0.0 |
| (Ord (g p), Ord (f p)) => Ord ((:*:) k f g p) | |
| (Read (g p), Read (f p)) => Read ((:*:) k f g p) | |
| (Show (g p), Show (f p)) => Show ((:*:) k f g p) | |
| Generic ((:*:) k f g p) | |
| type Rep1 k ((:*:) k f g) | |
| type Rep ((:*:) k f g p) | |
newtype ((f :: k2 -> *) :.: (g :: k1 -> k2)) (p :: k1) infixr 7 Source
Composition of functors
| Functor f => Generic1 k ((:.:) * k f g) | |
| (Functor g, Functor f) => Functor ((:.:) * * f g) | |
| (Applicative f, Applicative g) => Applicative ((:.:) * * f g) | Since: 4.9.0.0 |
| (Foldable f, Foldable g) => Foldable ((:.:) * * f g) | |
| (Traversable f, Traversable g) => Traversable ((:.:) * * f g) | |
| (Alternative f, Applicative g) => Alternative ((:.:) * * f g) | Since: 4.9.0.0 |
| Eq (f (g p)) => Eq ((:.:) k2 k1 f g p) | |
| (Typeable (* -> *) f, Typeable (* -> *) g, Data p, Data (f (g p))) => Data ((:.:) * * f g p) | Since: 4.9.0.0 |
| Ord (f (g p)) => Ord ((:.:) k2 k1 f g p) | |
| Read (f (g p)) => Read ((:.:) k2 k1 f g p) | |
| Show (f (g p)) => Show ((:.:) k2 k1 f g p) | |
| Generic ((:.:) k2 k1 f g p) | |
| type Rep1 k ((:.:) * k f g) | |
| type Rep ((:.:) k2 k1 f g p) | |
data family URec (a :: *) (p :: k) Source
Constants of unlifted kinds
Since: 4.9.0.0
| Generic1 k (URec k Word) | |
| Generic1 k (URec k Int) | |
| Generic1 k (URec k Float) | |
| Generic1 k (URec k Double) | |
| Generic1 k (URec k Char) | |
| Generic1 k (URec k (Ptr ())) | |
| Functor (URec * Char) | |
| Functor (URec * Double) | |
| Functor (URec * Float) | |
| Functor (URec * Int) | |
| Functor (URec * Word) | |
| Functor (URec * (Ptr ())) | |
| Foldable (URec * Char) | |
| Foldable (URec * Double) | |
| Foldable (URec * Float) | |
| Foldable (URec * Int) | |
| Foldable (URec * Word) | |
| Foldable (URec * (Ptr ())) | |
| Traversable (URec * Char) | |
| Traversable (URec * Double) | |
| Traversable (URec * Float) | |
| Traversable (URec * Int) | |
| Traversable (URec * Word) | |
| Traversable (URec * (Ptr ())) | |
| Eq (URec k Word p) | |
| Eq (URec k Int p) | |
| Eq (URec k Float p) | |
| Eq (URec k Double p) | |
| Eq (URec k Char p) | |
| Eq (URec k (Ptr ()) p) | |
| Ord (URec k Word p) | |
| Ord (URec k Int p) | |
| Ord (URec k Float p) | |
| Ord (URec k Double p) | |
| Ord (URec k Char p) | |
| Ord (URec k (Ptr ()) p) | |
| Show (URec k Word p) | |
| Show (URec k Int p) | |
| Show (URec k Float p) | |
| Show (URec k Double p) | |
| Show (URec k Char p) | |
| Generic (URec k Word p) | |
| Generic (URec k Int p) | |
| Generic (URec k Float p) | |
| Generic (URec k Double p) | |
| Generic (URec k Char p) | |
| Generic (URec k (Ptr ()) p) | |
| data URec k Word |
Used for marking occurrences of Since: 4.9.0.0 |
| data URec k Int |
Used for marking occurrences of Since: 4.9.0.0 |
| data URec k Float |
Used for marking occurrences of Since: 4.9.0.0 |
| data URec k Double |
Used for marking occurrences of Since: 4.9.0.0 |
| data URec k Char |
Used for marking occurrences of Since: 4.9.0.0 |
| data URec k (Ptr ()) |
Used for marking occurrences of Since: 4.9.0.0 |
| type Rep1 k (URec k Word) | |
| type Rep1 k (URec k Int) | |
| type Rep1 k (URec k Float) | |
| type Rep1 k (URec k Double) | |
| type Rep1 k (URec k Char) | |
| type Rep1 k (URec k (Ptr ())) | |
| type Rep (URec k Word p) | |
| type Rep (URec k Int p) | |
| type Rep (URec k Float p) | |
| type Rep (URec k Double p) | |
| type Rep (URec k Char p) | |
| type Rep (URec k (Ptr ()) p) | |
type UAddr = URec (Ptr ()) Source
Since: 4.9.0.0
Since: 4.9.0.0
type UDouble = URec Double Source
Since: 4.9.0.0
type UFloat = URec Float Source
Since: 4.9.0.0
Since: 4.9.0.0
Since: 4.9.0.0
Type synonym for encoding recursion (of kind *)
Tag for K1: recursion (of kind *)
Type synonym for encoding meta-information for datatypes
Type synonym for encoding meta-information for constructors
Type synonym for encoding meta-information for record selectors
Tag for M1: datatype
Tag for M1: constructor
Tag for M1: record selector
Class for datatypes that represent datatypes
datatypeName :: t d (f :: k -> *) (a :: k) -> [Char] Source
The name of the datatype (unqualified)
moduleName :: t d (f :: k -> *) (a :: k) -> [Char] Source
The fully-qualified name of the module where the type is declared
packageName :: t d (f :: k -> *) (a :: k) -> [Char] Source
The package name of the module where the type is declared
Since: 4.9.0.0
isNewtype :: t d (f :: k -> *) (a :: k) -> Bool Source
Marks if the datatype is actually a newtype
Since: 4.7.0.0
| (KnownSymbol n, KnownSymbol m, KnownSymbol p, SingI Bool nt) => Datatype Meta (MetaData n m p nt) | Since: 4.9.0.0 |
class Constructor c where Source
Class for datatypes that represent data constructors
conName :: t c (f :: k -> *) (a :: k) -> [Char] Source
The name of the constructor
conFixity :: t c (f :: k -> *) (a :: k) -> Fixity Source
The fixity of the constructor
conIsRecord :: t c (f :: k -> *) (a :: k) -> Bool Source
Marks if this constructor is a record
| (KnownSymbol n, SingI FixityI f, SingI Bool r) => Constructor Meta (MetaCons n f r) | Since: 4.9.0.0 |
Class for datatypes that represent records
selName, selSourceUnpackedness, selSourceStrictness, selDecidedStrictness
selName :: t s (f :: k -> *) (a :: k) -> [Char] Source
The name of the selector
selSourceUnpackedness :: t s (f :: k -> *) (a :: k) -> SourceUnpackedness Source
The selector's unpackedness annotation (if any)
Since: 4.9.0.0
selSourceStrictness :: t s (f :: k -> *) (a :: k) -> SourceStrictness Source
The selector's strictness annotation (if any)
Since: 4.9.0.0
selDecidedStrictness :: t s (f :: k -> *) (a :: k) -> DecidedStrictness Source
The strictness that the compiler inferred for the selector
Since: 4.9.0.0
| (SingI (Maybe Symbol) mn, SingI SourceUnpackedness su, SingI SourceStrictness ss, SingI DecidedStrictness ds) => Selector Meta (MetaSel mn su ss ds) | Since: 4.9.0.0 |
Datatype to represent the fixity of a constructor. An infix | declaration directly corresponds to an application of Infix.
| Prefix | |
| Infix Associativity Int |
This variant of Fixity appears at the type level.
Since: 4.9.0.0
| PrefixI | |
| InfixI Associativity Nat |
data Associativity Source
Datatype to represent the associativity of a constructor
| LeftAssociative | |
| RightAssociative | |
| NotAssociative |
Get the precedence of a fixity value.
data SourceUnpackedness Source
The unpackedness of a field as the user wrote it in the source code. For example, in the following data type:
data E = ExampleConstructor Int
{-# NOUNPACK #-} Int
{-# UNPACK #-} Int
The fields of ExampleConstructor have NoSourceUnpackedness, SourceNoUnpack, and SourceUnpack, respectively.
Since: 4.9.0.0
| NoSourceUnpackedness | |
| SourceNoUnpack | |
| SourceUnpack |
data SourceStrictness Source
The strictness of a field as the user wrote it in the source code. For example, in the following data type:
data E = ExampleConstructor Int ~Int !Int
The fields of ExampleConstructor have NoSourceStrictness, SourceLazy, and SourceStrict, respectively.
Since: 4.9.0.0
| NoSourceStrictness | |
| SourceLazy | |
| SourceStrict |
data DecidedStrictness Source
The strictness that GHC infers for a field during compilation. Whereas there are nine different combinations of SourceUnpackedness and SourceStrictness, the strictness that GHC decides will ultimately be one of lazy, strict, or unpacked. What GHC decides is affected both by what the user writes in the source code and by GHC flags. As an example, consider this data type:
data E = ExampleConstructor {-# UNPACK #-} !Int !Int Int
ExampleConstructor will have DecidedStrict, DecidedStrict, and DecidedLazy, respectively.-XStrictData enabled, then the fields will have DecidedStrict, DecidedStrict, and DecidedStrict, respectively.-O2 enabled, then the fields will have DecidedUnpack, DecidedStrict, and DecidedLazy, respectively.Since: 4.9.0.0
| DecidedLazy | |
| DecidedStrict | |
| DecidedUnpack |
Datatype to represent metadata associated with a datatype (MetaData), constructor (MetaCons), or field selector (MetaSel).
MetaData n m p nt, n is the datatype's name, m is the module in which the datatype is defined, p is the package in which the datatype is defined, and nt is 'True if the datatype is a newtype.MetaCons n f s, n is the constructor's name, f is its fixity, and s is 'True if the constructor contains record selectors.MetaSel mn su ss ds, if the field uses record syntax, then mn is Just the record name. Otherwise, mn is Nothing. su and ss are the field's unpackedness and strictness annotations, and ds is the strictness that GHC infers for the field.Since: 4.9.0.0
| MetaData Symbol Symbol Symbol Bool | |
| MetaCons Symbol FixityI Bool | |
| MetaSel (Maybe Symbol) SourceUnpackedness SourceStrictness DecidedStrictness |
| (KnownSymbol n, SingI FixityI f, SingI Bool r) => Constructor Meta (MetaCons n f r) | Since: 4.9.0.0 |
| (KnownSymbol n, KnownSymbol m, KnownSymbol p, SingI Bool nt) => Datatype Meta (MetaData n m p nt) | Since: 4.9.0.0 |
| (SingI (Maybe Symbol) mn, SingI SourceUnpackedness su, SingI SourceStrictness ss, SingI DecidedStrictness ds) => Selector Meta (MetaSel mn su ss ds) | Since: 4.9.0.0 |
Representable types of kind *. This class is derivable in GHC with the DeriveGeneric flag on.
Convert from the datatype to its representation
Convert from the representation to the datatype
class Generic1 (f :: k -> *) where Source
Representable types of kind * -> * (or kind k -> *, when PolyKinds is enabled). This class is derivable in GHC with the DeriveGeneric flag on.
from1 :: f a -> Rep1 f a Source
Convert from the datatype to its representation
Convert from the representation to the datatype
© The University of Glasgow and others
Licensed under a BSD-style license (see top of the page).
https://downloads.haskell.org/~ghc/8.2.1/docs/html/libraries/base-4.10.0.0/GHC-Generics.html